0 REM COPYRIGHT 1995 - COMPUTE PUBLICATIONS INTL LTD - ALL RIGHTS RESERVED
5 POKE53280,6:GOSUB 1109
10 RESTORE:LN=0:PRINT"[147]"
11 PRINTSPC(09)"[158]                     "
12 PRINTSPC(09)"[158]                     "
13 PRINTSPC(09)"[158]                     "
14 PRINT"   MAILING LIST    [158]"
15 PRINT
20 PRINTTAB(9) " F1 [146] LIST ALL LAST NAMES"
22 PRINTTAB(9) " F3 [146] SEARCH FOR NAME"
23 PRINTTAB(9) " F4 [146] TO ADD NAMES"
24 PRINTTAB(9) " F5 [146] ALL NAMES & ADDRESSES"
25 PRINTTAB(9) " F7 [146] TO QUIT"
50 GET Q$:IFQ$=""THEN 50
51 IFQ$="[138]"THENPRINT"[147]":LIST500-699
52 IFQ$="[133]"THENIFXN=1THENLN=1:X=0:GOTO1250
53 IFQ$="[133]"THENLN=1:X=0:PRINT"[147]  *** SORTING"NN"NAMES ***"
55 IFQ$="[133]"THEN1160
60 IFQ$="[134]"THEN300
62 IFQ$="[135]"THENPRINT"[147]":GOTO400
66 IFQ$="[136]"THEN700
70 GOTO 50
299 REM SEARCH FOR NAME
300 PRINT"[153][147]LAST NAME";:INPUTLL$:PRINT""
301 M=0
320 READL$,F$,A$,C$,S$,Z$,P$
325 IFL$=LL$THENPRINTF$" "L$ :GOTO330
327 IFL$<>"*"THEN320
328 IF M=1THEN360
329 IFL$ ="*"THEN PRINT"SORRY,  "LL$" [146] NOT LISTED.":FORDD=1TO2000:NEXT:GOTO10
330 PRINTA$
340 PRINTC$ ", "S$" ";
350 PRINTZ$
352 PRINTP$:PRINT:M=1
355 IFL$<>"*"THEN320
360 PRINT"[153] HIT SPACE BAR TO CONT. HIT P TO PRINT  "
370 GETA$:IFA$=""THEN370
375 IF A$="P"THENGOSUB1500
380 GOTO10
400 PRINT"[147]":I=0
401 I=I+1
402 READL$,F$,A$,C$,S$,Z$,P$
403 IFL$ ="*"THENI=4:GOTO410
404 PRINTF$" "L$
405 PRINTA$
407 PRINTC$" "S$" "Z$
408 PRINTP$:PRINT
410 IFI=4THEN PRINT"[153] HIT SPACE BAR TO CONT. ":GOTO420
418 IF L$<>"*" THEN401
420 GETSS$:IF SS$=""THEN420
424 IFL$="*"THEN 10
426 GOTO400
500 REM ADD NAMES TO DATA STATEMENTS
501 DATA LAST NAME,FIRST NAME, ADDRESS, CITY, STATE, ZIPCODE, PHONE NUMBER
502 DATA SMITH, JIM, 125 ELM ST. APT.#3,HOMETOWN,NC,27272,(555) 234-5678
503 DATA JONES, TOM,RT1 BOX 22,UPSTATE,NY,10000,NO PHONE
504 DATA SMITH, AL AND SUE, 123 ELM ST.,HOMETOWN,NC,27272,(555) 123-4567
698 DATA *
699 REM BE SURE TO RUN PROGRAM AGAIN    AFTER ADDING NAMES, THEN RESAVE.
700 PRINT"[147]"
702 PRINT"REMEMBER TO SAVE THE PROGRAM IF YOU     MADE ANY CHANGES TO THE LIST."
705 PRINT" NEED TO SAVE? (Y/N)[160][146]";
706 INPUTU$
708 IF U$="N"THEN715
710 IFU$="Y"THENOPEN15,8,15,"S0:MAILING LIST":CLOSE15:SAVE"MAILING LIST",8:GOTO715
712 GOTO700
715 PRINT:PRINTTAB(6)"THANKS...ALL FINISHED!"
716 END
1000 DATA*,*,*,*,*,*,*
1109 PRINT"[147]HANG ON A SEC..."
1110 CLR  :DIM L$(200),F$(200),A$(200),C$(200),S$(200),Z$(200),P$(200)
1140 READL$(NN),F$(NN),A$(NN),C$(NN),S$(NN),Z$(NN),P$(NN)
1142 IF L$(NN)="*"THEN 10
1150 NN=NN+1
1155 GOTO1140
1159 REM BUBBLE SORT
1160 FOR I= 0 TO NN
1170 FOR J =0 TO NN
1175 XN=1
1180 IF  L$(J) <  L$(I) THEN LN$=  L$(J): L$(J) = L$(I):  L$(I) = LN$
1190 NEXT J
1220 NEXT I
1250 PRINT"[147]"
1300 FOR J= NNTO 0 STEP -1
1301 X=X+1
1303 IF X<>20THEN1307
1304 IFX=20THENPRINT: PRINT"[153] HIT SPACE BAR ":X=0:PRINT
1305 GETA$:IFA$=""THEN1305
1306 PRINT"[147]"
1307 IFL$(J)="*"THENL$(J)="NAMES IN ALPHABETICAL ORDER:"
1310 PRINTL$(J)
1320 NEXT J
1330 PRINT:PRINT"[153]"NN"[157] NAMES IN DIRECTORY  "
1335 PRINT" HIT SPACE BAR TO CONT. "
1340 GETA$:IFA$=""THEN1340
1350 GOTO10
1500 REM PRINT ROUTINE
1505 OPEN4,4
1510 RESTORE
1520 READL$,F$,A$,C$,S$,Z$,P$
1522 IFL$="*"THEN CLOSE4:RETURN
1525 IFL$<>LL$THEN1520
1530 IFL$=LL$THENPRINT#4,F$" "L$
1533 PRINT#4,A$
1535 PRINT#4,C$ ", "S$" ";
1540 PRINT#4,Z$
1545 PRINT#4,P$:PRINT#4:M=1
1550 IFL$<>"*"THEN1520
1555 CLOSE4:RETURN